Amiga Format CD 44/Amiga Format CD44 (1999-08-26)(Future Publishing)(GB)(Track 1 of 3)[!][issue 1999-10].iso/-serious-/wb/meautostart/install

Text File | 1999-07-12 | 4KB | 240 lines

;**************************************************
;
; Installer-Script for MEAutoStart 1.5
;
;    Autor    : Malte Eller
;    Version    : 1.4
;    Datum    : 21.05.1999
;
;    $VER: Install 1.4 (21.05.1999)
;
;**************************************************

(set @user-level 1)

(if (= @language "deutsch")
 (
  (set #bad-kick (cat "Leider wird OS3.0 oder höher benötigt"))
  (set #askdir1 (cat "Wohin möchten Sie MEAutoStart installieren?\n"
   "(Dort wird dann eine neue Schubalde angelegt!)"))
  (set #fragetext (cat "Möchten Sie das Programm auch in die \n"
   " WBStartup kopieren?"))
  (set #ja (cat "Ja"))
  (set #nein (cat "Nein"))
  (set #confirmt (cat "Was möchten Sie installieren?"))
  (set #fragetextL (cat "Welche Sprachen möchten Sie installiern?"))
  (set #fragestart (cat "Möchten Sie MEAutoStart starten?"))
  (set #fragecon (cat "Möchten Sie die alten NamenFiles convertieren?"))
  (set #fragedel (cat "Möchten Sie die alten NamenFiles löschen?"))
 )

 (
  (set #bad-kick (cat "Sorry, I need OS3.0 or higher"))
  (set #askdir1 (cat "In which Drawer will you install MEAutoStart?\n"
  "(A new Drawer will be create!)"))
  (set #fragetext (cat "Should I copy the Program to WBStartup?"))
  (set #ja (cat "Yes"))
  (set #nein (cat "No"))
  (set #confirmt (cat "What should I install?"))
  (set #fragetextL (cat "Which languages should I install?"))
  (set #fragestart (cat "Would you start MEAutoStart?"))
  (set #fragecon (cat "Would you convert the old namefiles?"))
  (set #fragedel (cat "Would you delete the olf namefiles?"))
 )
)

;**************************************************

(if (< (/ (getversion) 65536) 39)
    (
            (abort #bad-kick)
    )
)

;**************************************************

(complete 0)

(
    (set #name
        (askdir
            (prompt #askdir1)
            (help @askdir-help)
            (default "SYS:Tools")
        )
    )

    (set #Dname
        (tackon #name "MEAutoStart")
    )

    (makedir #Dname
        (infos)
    )

    (copyfiles
        (source "")
        (dest #Dname)
        (pattern "#?")
        (prompt #confirmt)
        (help @confirm-help)
        (confirm)
    )
)

(complete 50)

;**************************************************

(set name
    (askoptions
        (prompt #fragetext)
        (help @askoptions-help)
        (choices #Ja)
        (default 1)
    )
)


(if (= 1 name)
    (
        (copyfiles
            (source "MEAutoStart")
            (dest "sys:WBStartup")
            (prompt #fragetext)
            (help @confirm-help)
            (confirm)
         )

         (if (not (exists "sys:WBStartup/MEAutoStart.info"))
             (
                 (copyfiles
                    (source "MEAutoStart.info")
                    (dest "sys:WBStartup")
                    (prompt #fragetext)
                    (help @confirm-help)
                    (confirm)
                )
            )
         )
    )
)


(if (not (exists "envarc:MEAutoStart.Liste"))
    (
        (copyfiles
            (source "MEAutoStart.Liste")
            (dest "envarc:")
        )
    )
)


(if (exists "envarc:MEAutoStart.ja")
    (
         (set #startcon "MEASConvert")

        (set name
            (askoptions
                (prompt #fragecon)
                (help @askoptions-help)
                (choices #Ja)
                (default 1)
            )
        )
        (if (= 1 name)
            (
                (run #startcon)
            )
        )
        (set #delold1 "delete envarc:MEAutoStart.Ja")
        (set #delold2 "delete envarc:MEAutoStart.nein")

        (set name
            (askoptions
                (prompt #fragedel)
                (help @askoptions-help)
                (choices #Ja)
                (default 1)
            )
        )
        (if (= 1 name)
            (
                (run #delold1)
                (run #delold2)
            )
        )
    )
)

(complete 80)

;**************************************************

(if (exists "sys:locale/catalogs")
    (set #lang (askoptions
        (prompt #fragetextL)
        (help @askoptions-help)
        (choices "Deutsch" "English")
        (default 1))
     )
)

(set #n 0)

(while
    (set #sprache
         (select #n
             "Deutsch"
             "English"
             ""
         )
     )
    (
     (if (IN #lang #n)
        (
         (set #catalog (tackon "Catalogs" (tackon #sprache "MEAutoStart.catalog")))
         (set #destination (tackon "Locale:Catalogs/" #sprache))
         (copyfiles
            (source #catalog)
            (dest #destination)
            (prompt #confirmt)
            (help @confirm-help)
            (confirm))
         (set #guide (tackon "Docs" (tackon #sprache "MEAutostart.guide")))
         (set #destination (tackon "Help:" #sprache))
          (copyfiles
            (source #guide)
            (dest #destination)
            (prompt #confirmt)
            (help @confirm-help)
            (confirm)
          )

        )
     )
     (set #n (+ #n 1))
    )
)

(
    (set #startpf "run MEAutostart P")

    (set name
        (askoptions
            (prompt #fragestart)
            (help @askoptions-help)
            (choices #Ja)
            (default 1)
        )
    )
    (if (= 1 name)
        (
            (run #startpf)
        )
    )
)

(complete 100)